Windows 10 Start menu search blank

@echo off

title Disable/Enable Windows 10 Search Bar Internet Searching
color 1f
:Begin UAC check and Auto-Elevate Permissions
:-------------------------------------
REM  --> Check for permissions
>nul 2>&1 "%SYSTEMROOT%\system32\cacls.exe" "%SYSTEMROOT%\system32\config\system"

REM --> If error flag set, we do not have admin.
if '%errorlevel%' NEQ '0' (
echo:
echo   Requesting Administrative Privileges...
echo   Press YES in UAC Prompt to Continue
echo:

    goto UACPrompt
) else ( goto gotAdmin )

:UACPrompt
    echo Set UAC = CreateObject^("Shell.Application"^) > "%temp%\getadmin.vbs"
    echo UAC.ShellExecute "%~s0", "", "", "runas", 1 >> "%temp%\getadmin.vbs"

    "%temp%\getadmin.vbs"
    exit /B

:gotAdmin
    if exist "%temp%\getadmin.vbs" ( del "%temp%\getadmin.vbs" )
    pushd "%CD%"
    CD /D "%~dp0"
:--------------------------------------

:Check Windows Version
wmic os get version | find /i "10.">nul 2>nul
if %errorlevel% neq 0 GOTO :Not10

:Check the key:
reg query "HKLM\SOFTWARE\Policies\Microsoft\Windows\Windows Search" /v "ConnectedSearchUseWeb">NUL 2>NUL
if %errorlevel% neq 0 GOTO :KEYON
(reg query "HKLM\SOFTWARE\Policies\Microsoft\Windows\Windows Search" /v "ConnectedSearchUseWeb"|find /i "0x1")>NUL 2>NUL
if %errorlevel% neq 0 GOTO :KEYOFF

:KEYON
echo ============================================================
echo Web searching in search box is currently enabled.
echo Would you like to disable this? (Y/N)
echo ============================================================
echo.
choice /c yn /n
If %ERRORLEVEL% NEQ 1 GOTO :QUIT


Echo Changing Registry key
REG ADD "HKLM\SOFTWARE\Policies\Microsoft\Windows\Windows Search" /v "ConnectedSearchUseWeb" /D 0 /T REG_DWORD /F>NUL 2>NUL
if exist c:\windows\syswow64 REG ADD "HKLM\SOFTWARE\Wow6432Node\Policies\Microsoft\Windows\Windows Search" /v "ConnectedSearchUseWeb" /D 0 /T REG_DWORD /F>NUL 2>NUL
IF %ERRORLEVEL% NEQ 0 GOTO :ERROR
Echo.

Echo Web searching in search box has been disabled.
Echo.
goto :QUIT


:KEYOFF
echo ============================================================
echo Web searching in search box is currently disabled.
echo Would you like to enable this? (Y/N)
echo ============================================================
echo.
choice /c yn /n
If %ERRORLEVEL% NEQ 1 GOTO :QUIT

Echo Changing Registry key
REG ADD "HKLM\SOFTWARE\Policies\Microsoft\Windows\Windows Search" /v "ConnectedSearchUseWeb" /D 1 /T REG_DWORD /F>NUL 2>NUL
IF %ERRORLEVEL% NEQ 0 GOTO :ERROR
if exist c:\windows\syswow64 REG ADD "HKLM\SOFTWARE\Wow6432Node\Policies\Microsoft\Windows\Windows Search" /v "ConnectedSearchUseWeb" /D 1 /T REG_DWORD /F>NUL 2>NUL
IF %ERRORLEVEL% NEQ 0 GOTO :ERROR
Echo.

Echo Web searching in search box has been enabled.
Echo.
goto :QUIT


:QUIT
echo ============================================================
echo Press any key to exit...
echo ============================================================
pause>NUL
goto :EOF

:ERROR
echo ============================================================
echo The script ran into an unexpected error setting reg key.
echo Press any key to exit...
echo ============================================================
pause>NUL
goto :EOF

:Not10
echo ============================================================
echo This script is only designed for Windows 10...
echo Press any key to exit...
echo ============================================================
pause>NUL
goto :EOF