english/german XP?

Archived from groups: microsoft.public.windowsxp.configuration_manage (More info?)

Hi guys,


I would have 2 questions and hope anybody can answer. Thanks in advance.


1.. What´s the "exact" difference between an English & German OS (XP)?
- Is it only the Default settings within the "Regional and Language
Options"?


2.. Where can I see which OS was installed actually? Is there anywhere a
status within the Settings or anywhere in the system information, registry
etc. ?


Thanks a million

Maik
2 answers Last reply
More about english german
  1. Archived from groups: microsoft.public.windowsxp.configuration_manage (More info?)

    Maik Richter wrote:


    > I would have 2 questions and hope anybody can answer. Thanks in advance.
    >
    > 1.. What´s the "exact" difference between an English & German OS (XP)?
    > - Is it only the Default settings within the "Regional and
    > Language Options"?

    No, it's much more than that. In the German version, all standard menu
    names and text in dialog boxes is in German. You will notice the
    difference, that I can guarantee you ;-)


    > 2.. Where can I see which OS was installed actually? Is there
    > anywhere a status within the Settings or anywhere in the system
    > information, registry etc. ?

    The VBScript below will give you this output in a Notepad document:

    OS version: Microsoft Windows XP Professional
    SP version: Service Pack 2
    OS language: English
    Regional Settings for user is set to: Norway


    Put the following inside a file called OSSettings.vbs
    and launch it by double clicking it.

    '--------------------8<----------------------
    sComputer = "." ' use "." for local computer

    Set oShell = CreateObject("WScript.Shell")

    On Error Resume Next
    Set oWMI = GetObject("winmgmts:" _
    & "{impersonationLevel=impersonate}!\\" & sComputer _
    & "\root\cimv2")

    If Err.Number = 0 Then
    Set colOperatingSystems = oWMI.ExecQuery _
    ("Select * from Win32_OperatingSystem")

    For Each oOS in colOperatingSystems

    iOSLang = oOS.OSLanguage
    sOSLangHex = Right("000" & Hex(iOSLang), 4)

    sOSCaption = oOS.Caption
    sOSServicePack = oOS.CSDVersion
    Next

    Const HKCU = &H80000001
    Const HKLM = &H80000002

    Set oReg=GetObject("winmgmts:{impersonationLevel=impersonate}!\\" _
    & sComputer & "\root\default:StdRegProv")

    sOSLanguage = "Unknown" ' Init value
    sKeyPath = "SOFTWARE\Classes\MIME\Database\Rfc1766"
    sValueName = sOSLangHex
    oReg.GetStringValue HKLM, sKeyPath, sValueName, sOSLanguage

    ' remove unnecessary stuff
    aOSLanguage = Split(sOSLanguage, ";")
    sOSLanguage = aOSLanguage(UBound(aOSLanguage))
    If Instr(sOSLanguage, "(") > 0 Then
    aOSLanguage = Split(sOSLanguage, "(")
    sOSLanguage = Trim(aOSLanguage(0))
    End If

    sKeyPath = "Control Panel\International"
    sValueName = "sCountry"
    oReg.GetStringValue HKCU, sKeyPath, sValueName, sCountry
    On Error Goto 0

    Set oFSO = CreateObject("Scripting.FileSystemObject")
    Const OpenAsASCII = 0
    sTmpFile = oShell.ExpandEnvironmentStrings("%TEMP%\tmp_sysinfo.txt")
    Set fTmpFile = oFSO.CreateTextFile(sTmpFile, True, OpenAsASCII)

    fTmpFile.WriteLine "OS version: " & sOSCaption
    fTmpFile.WriteLine "SP version: " & sOSServicePack
    fTmpFile.WriteLine "OS language: " & sOSLanguage

    fTmpFile.WriteLine "Regional Settings for user is set to: " & sCountry

    fTmpFile.Close
    oShell.Run "Notepad " & sTmpFile
    Else
    Wscript.Echo "Error, could not connect with WMI!"
    End If
    On Error Goto 0

    '--------------------8<----------------------


    --
    torgeir, Microsoft MVP Scripting and WMI, Porsgrunn Norway
    Administration scripting examples and an ONLINE version of
    the 1328 page Scripting Guide:
    http://www.microsoft.com/technet/scriptcenter/default.mspx
  2. Archived from groups: microsoft.public.windowsxp.configuration_manage (More info?)

    1. In German XP everything is in german. Regional settings keeps everything in english (on english XP) only changing the ability to work in german.

    2. Look at Start or something. If german then german. Yov don't need german XP to work in German. Programs typically keep langvage within themselves so most programs will be whatever langvage they are.

    EG Installing an english langvage version of a program then that program's menvs etc will appear in whatever langvage that program is on either german or english XP.

    3. Bvt a better solvtion is to wait for fvrther EU integration.

    The Evropean Union commissioners have annovnced that an
    agreement has been reached to adopt English as the preferred langvage
    for Evropean commvnications, rather than German, which was the other
    possibility.

    As part of the negotiations, the British government conceded that
    English spelling had some room for improvement and has accepted a
    5-year phased plan for what will be known as EvroEnglish (Evro for
    short).

    In the first year, "s" will be vsed instead of the soft "c". Sertainly,
    sivil
    servants will resieve this news with joy. Also, the hard "c" will be
    replased
    with "k". Not only will this klear vp konfvsion, bvt typewriters kan have
    one less letter.

    There will be growing pvblik enthvsiasm in the sekond year, when the
    trovblesome "ph" will be replaced by f". This will make words like
    "fotograf" 20 per sent shorter.

    In the 3rd year, pvblik akseptanse of the new spelling kan be expekted
    to reach the stage where more komplikated changes are possible.
    Governments will enkorage the removal of dovble letters, which have
    always ben a deterent to akvrate speling. Also, al wil agre that the
    horible

    mes of silent "e"s in the langvag is disgrasfvl, and they wovld go.

    By the 4th year, peopl wil be reseptiv to steps svch as replasing "th" by
    "z" and "w" by "v".

    Dvring yer 5, ze vnesesary "o" kan be dropd from vords kontaining "ov",
    and similar changes vvd of kors be aplid to ozer kombinations of leters.
    Und efter ze fifz yer, ve vil al be speking German like zey vvnted in ze
    forst plas.

    --
    ----------------------------------------------------------
    War on the Pachyderms Terrorists
    http://www.covnterpvnch.org/wilson09012004.html
    "Maik Richter" <maik.richter2@gmx.de> wrote in message news:e6c1oewmEHA.3464@tk2msftngp13.phx.gbl...
    > Hi gvys,
    >
    >
    >
    > I wovld have 2 qvestions and hope anybody can answer. Thanks in advance.
    >
    >
    >
    > 1.. What´s the "exact" difference between an English & German OS (XP)?
    > - Is it only the Defavlt settings within the "Regional and Langvage
    > Options"?
    >
    >
    >
    > 2.. Where can I see which OS was installed actvally? Is there anywhere a
    > statvs within the Settings or anywhere in the system information, registry
    > etc. ?
    >
    >
    > Thanks a million
    >
    > Maik
    >
    >
Ask a new question

Read More

Configuration Microsoft Windows XP